Current Path : /usr/share/zsh/4.3.11/functions/

Upload File :

Current File : //usr/share/zsh/4.3.11/functions/VCS_INFO_hook

### vim:ft=zsh:foldmethod=marker
## Written by Frank Terbeck <ft@bewatermyfriend.org>
## Distributed under the same BSD-ish license as zsh itself.

local hook func
local -x context hook_name
local -xi ret
local -a hooks
local -i debug

ret=0
hook_name="$1"
shift
context=":vcs_info:${vcs}+${hook_name}:${usercontext}:${rrn}"

zstyle -t "${context}" debug && debug=1 || debug=0
if (( debug )); then
    printf 'VCS_INFO_hook: running hook: "%s"\n' "${hook_name}"
    printf 'VCS_INFO_hook: current context: "%s"\n' "${context}"
fi

zstyle -a "${context}" hooks hooks || return 0
# Protect some internal variables in hooks. The `-g' parameter to
# typeset does *not* make the parameters global here (they are already
# "*-local-export). It prevents typeset from creating *new* *local*
# parameters in this function's scope.
typeset -g -r vcs rrn usercontext maxexports msgs vcs_comm
for hook in ${hooks} ; do
    func="+vi-${hook}"
    if (( ${+functions[$func]} == 0 )); then
        (( debug )) && printf '  + Unknown function: "%s"\n' "${func}"
        continue
    fi
    (( debug )) && printf '  + Running function: "%s"\n' "${func}"
    true
    ${func} "$@"
    case $? in
        (0)
            ;;
        (*)
            break
            ;;
    esac
done
typeset -g +r vcs rrn usercontext maxexports msgs vcs_comm
return $ret

Copyright 2K16 - 2K18 Indonesian Hacker Rulez