Current Path : /home/thomas/public_html/Fox-C404/root/scripts/

Upload File :

Current File : /home/thomas/public_html/Fox-C404/root/scripts/swapip

#!/usr/local/cpanel/3rdparty/bin/perl
package scripts::swapip;

# cpanel - scripts/swapip                            Copyright 2017 cPanel, Inc.
#                                                           All Rights Reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited
#

use strict;
use warnings;

use Cpanel::BinCheck::Lite        ();
use Cpanel::LoadModule            ();
use Cpanel::JSON                  ();
use Cpanel::DnsUtils::AskDnsAdmin ();
use Cpanel::ZoneFile              ();
use Cpanel::Encoder::URI          ();
use Cpanel::DnsUtils::Fetch       ();
use Cpanel::NAT                   ();
use Whostmgr::Transfers::State    ();
use Whostmgr::DNS::SwapIP         ();

Cpanel::BinCheck::Lite::check_argv();

## if invoked as a script, there is nothing in the call stack
my $invoked_as_script = !caller();
__PACKAGE__->script(@ARGV) if ($invoked_as_script);

sub script {
    my ( $package, @args ) = @_;

    my ( $sourceip, $targetip, @DOMAINS, $zoneref, $showmsgs, $skipsync, $skipreload, $ftpip, $replaceip );

    my $input_ref;

    if ( @args && $args[0] eq '--json' ) {
        $input_ref = Cpanel::JSON::LoadFileNoSetUTF8( \*STDIN );
    }
    elsif ( @args && $args[0] eq '--storable' ) {
        Cpanel::LoadModule::load_perl_module('Cpanel::SafeStorable');
        $input_ref = Cpanel::SafeStorable::fd_retrieve( \*STDIN );
    }
    elsif ( ref $args[0] ) {
        $input_ref = $args[0];
    }
    else {
        $sourceip = shift(@args);
        $targetip = shift(@args);
        $ftpip    = shift(@args);
        @DOMAINS  = @args;
    }

    if ($input_ref) {
        $sourceip = $input_ref->{'sourceip'};
        $targetip = ( $input_ref->{'destip'} || $input_ref->{'targetip'} );

        @DOMAINS    = @{ $input_ref->{'domainref'} };
        $zoneref    = $input_ref->{'zoneref'};
        $showmsgs   = $input_ref->{'showmsgs'};
        $skipreload = $input_ref->{'skipreload'};
        $skipsync   = $input_ref->{'skipsync'};
        $replaceip  = $input_ref->{'replaceip'};

    }

    if ( ref $sourceip eq 'ARRAY' ) {
        foreach my $ip (@$sourceip) {
            $ip = Cpanel::NAT::get_public_ip($ip);
        }
    }
    else {
        $sourceip = Cpanel::NAT::get_public_ip($sourceip);
    }

    $targetip = Cpanel::NAT::get_public_ip($targetip);
    $ftpip    = Cpanel::NAT::get_public_ip($ftpip);

    if ( !$zoneref || !ref $zoneref ) {
        $zoneref = {};
    }

    if ( !@DOMAINS ) {
        print "At least one domain is required.\n";
        die_usage();
    }

    if ( !$sourceip ) {
        print "Error: sourceip missing\n";
        die_usage();
    }

    if ( !$targetip ) {
        print "Error: targetip missing\n";
        die_usage();
    }

    my $changes = _changezones( \@DOMAINS, $sourceip, $targetip, $ftpip, $zoneref, $showmsgs, $skipreload, $skipsync, $replaceip );

    print "The system updated “$changes” " . ( $changes == 1 ? 'entry' : 'entries' ) . ".\n";

    return 0;
}

sub _changezones {
    my $domainref = shift;
    my $sourceip  = shift;
    ## TODO: rename? why is this called $destip here but $targetip above?
    my $destip     = shift;
    my $ftpip      = shift;
    my $zoneref    = shift;
    my $showmsgs   = shift || 0;
    my $skipreload = shift || 0;
    my $skipsync   = shift || 0;
    my $replaceip  = shift || 'all';

    my %sourceips;
    if ($sourceip) {
        if ( ref $sourceip ) {
            %sourceips = map { $_ => 1 } @{$sourceip};
        }
        elsif ( $sourceip ne -1 ) {
            $sourceips{$sourceip} = 1;
        }
        delete $sourceips{''};    #safety
    }

    my @fetchlist;
    foreach my $domain (@$domainref) {
        if ( !$zoneref->{$domain} ) {
            push @fetchlist, $domain;
        }
    }

    my $_dns_local = Whostmgr::Transfers::State::is_transfer() ? $Cpanel::DnsUtils::AskDnsAdmin::LOCAL_ONLY : $Cpanel::DnsUtils::AskDnsAdmin::REMOTE_AND_LOCAL;
    my $replaced   = 0;
    if (@fetchlist) {

        my $added_zoneref = Cpanel::DnsUtils::Fetch::fetch_zones( 'zones' => \@fetchlist, 'flags' => $_dns_local );
        @{$zoneref}{ keys %$added_zoneref } = values %$added_zoneref;
    }

    foreach my $zone ( keys %$zoneref ) {
        my $zf = Cpanel::ZoneFile->new( 'text' => $zoneref->{$zone}, 'domain' => $zone );

        if ( !scalar keys %sourceips ) {
            my $previous_ip = Whostmgr::DNS::SwapIP::get_sourceip_from_zonefile_obj($zf) or next;
            $sourceips{$previous_ip} = 1;
        }

        $replaced += Whostmgr::DNS::SwapIP::swap_zonefile_obj_ips(
            'sourceips_hr'  => \%sourceips,
            'domain'        => $zone,
            'zone_file_obj' => $zf,
            'destip'        => $destip,
            'replaceip'     => $replaceip
        );

        $replaced += Whostmgr::DNS::SwapIP::swap_zonefile_spf_ips(
            'sourceips_hr'  => \%sourceips,
            'domain'        => $zone,
            'zone_file_obj' => $zf,
            'destip'        => $destip,
        );

        $zf->increase_serial_number();

        # it is critical that that hashref of zones is updated so multiple ip changes operate on the new zone
        $zoneref->{$zone} = $zf->to_zone_string();

    }

    my $zdata;
    my @RELOADLIST;
    foreach my $zone ( keys %$zoneref ) {
        if ( !$zoneref->{$zone} ) {
            next();
        }

        if ($showmsgs) { print "Changed $replaceip instances of [" . join( ',', keys %sourceips ) . "] -> [$destip] in $zone\n"; }

        push @RELOADLIST, $zone;

        $zdata .= 'cpdnszone-' . Cpanel::Encoder::URI::uri_encode_str($zone) . '=' . Cpanel::Encoder::URI::uri_encode_str( $zoneref->{$zone} ) . '&';
    }

    if ( !$skipsync ) {
        Cpanel::DnsUtils::AskDnsAdmin::askdnsadmin( 'SYNCZONES', $_dns_local, '', '', '', $zdata );
    }
    if ( !$skipreload ) { Cpanel::DnsUtils::AskDnsAdmin::askdnsadmin( 'RELOADZONES', $_dns_local, join( ',', @RELOADLIST ) ); }
    return $replaced;
}

sub die_usage {
    die "Usage: $0 sourceip destip ftpip domains...\n";
}

1;

Copyright 2K16 - 2K18 Indonesian Hacker Rulez